Está en Datos abiertos SPARQL

Formulario SPARQL

Puede realizar una consulta SPARQL arbitraria utilizando el formulario que aparece a continuación. Consulte la referencia del lenguaje SPARQL para obtener más información.

Consultas SPARQL de muestra

A continuación se presentan un conjunto de consultas SPARQL de ejemplo que pueden servirle como punto de partida para realizar otras personalizadas, o para familiarizarse con el lenguaje.

¿De qué autores hay obras impresas en el siglo XVII en la Biblioteca Dixital de Galicia?

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (MIN(?autor) AS ?Autor) (?x AS ?URIdelAutor) (count(?obra) AS ?NumObrasSigloXVII)
WHERE {
  ?obra dc:creator ?x.
  ?x skos:prefLabel ?autor.
  ?obra dc:date ?fecha.
  FILTER( ?fecha >=("1601") && ?fecha <("1700") )
} 
GROUP BY ?x
ORDER BY DESC(count(?obra))

Impresores de obras impresas en el siglo XVI en la Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?Impresor (COALESCE(MIN(?NombreImpresor), ?Impresor) AS ?Nombre) (count(?p) AS ?NumObrasImpresasSigloXVI)
WHERE {
  ?p dc:publisher ?Impresor; dc:date ?fecha.
  OPTIONAL { ?Impresor skos:prefLabel ?NombreImpresor }
  FILTER( ?fecha >=("1501") && ?fecha <=("1600") )
}
GROUP BY ?Impresor
ORDER BY DESC(count(?p))

Materias más tratadas en los libros del siglo XVIII de la Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (?materia AS ?Materia) (MIN(?etiqueta) as ?EtiquetaMateria) (COUNT(?p) AS ?NumObrasSigloXVIII)
WHERE { 
  ?p dc:date ?fecha; dc:subject ?materia. 
  ?materia skos:prefLabel ?etiqueta. 
  FILTER( ?fecha >=("1701") && ?fecha <("1800") )
}
GROUP BY ?materia
ORDER BY DESC(COUNT(?p))

Editores/impresores de las obras de Benito Feijoo en la Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT (?z AS ?Editor)
WHERE { 
  ?p dc:creator/skos:prefLabel ?x; dc:publisher ?z.
  FILTER (CONTAINS(?x, "Feijoo, Benito"))
}