Está en: › Datos abertos › SPARQL

Formulario SPARQL

Pode realizar unha consulta SPARQL arbitraria utilizando o formulario que aparece a continuación. Consulte a referencia da linguaxe SPARQL para obter máis información.

Formato de saída

Grafo por defecto

Consultas SPARQL de mostra

A continuación preséntanse un conxunto de consultas SPARQL de exemplo que poden servirlle como punto de partida para realizar outras personalizadas, ou para familiarizarse coa linguaxe.

De que autores hai obras impresas no século XVII na Biblioteca Dixital de Galicia?

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (MIN(?autor) AS ?Autor) (?x AS ?URIdelAutor) (count(?obra) AS ?NumObrasSigloXVII)
WHERE {
  ?obra dc:creator ?x.
  ?x skos:prefLabel ?autor.
  ?obra dc:date ?fecha.
  FILTER( ?fecha >=("1601") && ?fecha <("1700") )
} 
GROUP BY ?x
ORDER BY DESC(count(?obra))

Impresores de obras impresas no século XVI na Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?Impresor (COALESCE(MIN(?NombreImpresor), ?Impresor) AS ?Nombre) (count(?p) AS ?NumObrasImpresasSigloXVI)
WHERE {
  ?p dc:publisher ?Impresor; dc:date ?fecha.
  OPTIONAL { ?Impresor skos:prefLabel ?NombreImpresor }
  FILTER( ?fecha >=("1501") && ?fecha <=("1600") )
}
GROUP BY ?Impresor
ORDER BY DESC(count(?p))

Materias máis tratadas nos libros do século XVIII na Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (?materia AS ?Materia) (MIN(?etiqueta) as ?EtiquetaMateria) (COUNT(?p) AS ?NumObrasSigloXVIII)
WHERE { 
  ?p dc:date ?fecha; dc:subject ?materia. 
  ?materia skos:prefLabel ?etiqueta. 
  FILTER( ?fecha >=("1701") && ?fecha <("1800") )
}
GROUP BY ?materia
ORDER BY DESC(COUNT(?p))

Editores/impresores das obras de Benito Feijoo na Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT (?z AS ?Editor)
WHERE { 
  ?p dc:creator/skos:prefLabel ?x; dc:publisher ?z.
  FILTER (CONTAINS(?x, "Feijoo, Benito"))
}