You are at: › Datos abiertos › SPARQL

SPARQL form

You can perform SPARQL queries using the form that appears below this text. Please visit the SPARQL Query language documentation for information of writing SPARQL queries.

Output format

Default graph

Sample SPARQL queries

You can use the following sample queries as a starting point to build your own, or to get to know the SPARQL query language.

Which authors' printed works from the 17th century are present in the Biblioteca Dixital de Galicia?

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (MIN(?autor) AS ?Author) (?x AS ?AuthorURI) (count(?obra) AS ?WorkCount17thCentury)
WHERE {
  ?obra dc:creator ?x.
  ?x skos:prefLabel ?autor.
  ?obra dc:date ?fecha.
  FILTER( ?fecha >=("1601") && ?fecha <("1700") )
} 
GROUP BY ?x
ORDER BY DESC(count(?obra))

Publishers of works printed in the 16th century present in the Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?Impresor (COALESCE(MIN(?NombreImpresor), ?Impresor) AS ?Name) (count(?p) AS ?PrintedWorkCount16thCentury)
WHERE {
  ?p dc:publisher ?Impresor; dc:date ?fecha.
  OPTIONAL { ?Impresor skos:prefLabel ?NombreImpresor }
  FILTER( ?fecha >=("1501") && ?fecha <=("1600") )
}
GROUP BY ?Impresor
ORDER BY DESC(count(?p))

Most common subjects in printed works from the 18th century present in the Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT (?materia AS ?Subject) (MIN(?etiqueta) as ?SubjectLabel) (COUNT(?p) AS ?WorkCount18thCentury)
WHERE { 
  ?p dc:date ?fecha; dc:subject ?materia. 
  ?materia skos:prefLabel ?etiqueta. 
  FILTER( ?fecha >=("1701") && ?fecha <("1800") )
}
GROUP BY ?materia
ORDER BY DESC(COUNT(?p))

Publishers/editors of works written by Benito Feijoo present in the Biblioteca Dixital de Galicia

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT (?z AS ?Publisher)
WHERE { 
  ?p dc:creator/skos:prefLabel ?x; dc:publisher ?z.
  FILTER (CONTAINS(?x, "Feijoo, Benito"))
}